import md5, os, osproc, parseopt2, strutils, parsecfg, streams, lapp, subexes

# blimp is a little utility program for handling large files
# in git repositories. Its inspired by git-fat and s3annex
# but doesn't rely on S3 for storage, is a single binary without
# need for Python, and has less features than git-fat. So far.
#
# Manual use:
#
# Use "blimp d mybigfile" to deflate it before commit.
# Use "blimp i mybigfile" to inflate it back to original size.
#
# When deflated the file only has an md5sum string inside it.
#
# The file is copied over into:
#  <homedir>/blimpStore/<originalfilename>-<md5sum>
#
# Configuration is in:
#   <gitroot>/.blimp.conf
#   ~/blimpstore/.blimp.conf

var
  blimpStore, uploadCommandFormat, downloadCommandFormat, deleteCommandFormat, rsyncPassword: string
  remoteBlimpStore: string = nil
  verbose: bool

let
  defaultConfig = """
[rsync]
# Set this to your remote rsync daemon area
remote = "blimpuser@some-rsync-server.com::blimpstore"
password = some-good-rsync-password-for-blimpuser

# The following three formats should not need editing
# $1 is filename, $2 is remote and $3 is the local blimpstore
upload = "rsync --password-file $3/.blimp.pass -avzP $3/$1 $2/"
download = "rsync --password-file $3/.blimp.pass -avzP $2/$1 $3/"
# This deletes a single file from destination, that is already deleted in source
delete = "rsync --password-file $3/.blimp.pass -dv --delete --existing --ignore-existing --include '$1' --exclude '*' $3/ $2"
"""

# Load blimp.conf file, overkill for now but...
proc parseConfFile(filename: string) =
  var f = newFileStream(filename, fmRead)
  if f != nil:
    var p: CfgParser
    open(p, f, filename)
    while true:
      var e = next(p)
      case e.kind
      of cfgEof: 
        break
      of cfgSectionStart:
        continue # Ignore
      of cfgKeyValuePair:
        case e.key
        of "remote":
          remoteBlimpStore = e.value
        of "upload":
          uploadCommandFormat = e.value
        of "download":
          downloadCommandFormat = e.value
        of "delete":
          deleteCommandFormat = e.value
        of "password":
          rsyncPassword = e.value
        else:
          quit("Unknown configuration: " & e.key)
      of cfgOption:
        quit("Unknown configuration: " & e.key)
      of cfgError:
        quit("Parsing " & filename & ": " & e.msg)
    close(p)

# Trivial helper to enable verbose
proc run(cmd: string): auto =
  if verbose: echo(cmd)
  execCmd(cmd)

# Every rsync command, make sure we have a password file
proc rsyncRun(cmd: string): auto =
  writeFile(blimpStore / ".blimp.pass", rsyncPassword)
  if execCmd("chmod 600 " & blimpStore / ".blimp.pass") != 0:
    quit("Failed to chmod 600 " & blimpStore / ".blimp.pass")
  run(cmd)

# Upload a file to the remote master blimpStore
proc uploadFile(blimpFilename: string) =
  if remoteBlimpStore.isNil:
    echo("Remote blimpstore not set in configuration file, skipping uploading content:\n\t" & blimpFilename)
    return
  let errorCode = rsyncRun(format(uploadCommandFormat, blimpFilename, remoteBlimpStore, blimpStore))
  if errorCode != 0:
    quit("Something went wrong uploading " & blimpFilename & " to " & remoteBlimpStore, 2)
  
# Download a file to the remote master blimpStore
proc downloadFile(blimpFilename: string) =
  if remoteBlimpStore.isNil:
    quit("Remote blimpstore not set in configuration file, can not download content:\n\t" & blimpFilename)
  let errorCode = rsyncRun(format(downloadCommandFormat, blimpFilename, remoteBlimpStore, blimpStore))
  if errorCode != 0:
    quit("Something went wrong downloading " & blimpFilename & " from " & remoteBlimpStore, 3)

# Delete a file from the remote master blimpStore
proc remoteDeleteFile(blimpFilename: string) =
  if remoteBlimpStore.isNil:
    return
  let errorCode = rsyncRun(format(deleteCommandFormat, blimpFilename, remoteBlimpStore, blimpStore))
  if errorCode != 0:
    quit("Something went wrong deleting " & blimpFilename & " from " & remoteBlimpStore, 3)

# Copy content to blimpStore, no upload yet.
proc copyToBlimpStore(filename, blimpFilename: string) =
  if not existsFile(blimpStore / blimpFilename):
    copyFile(filename, blimpStore / blimpFilename)
    uploadFile(blimpFilename)

# Copy content from blimpStore, and downloading first if needed
proc copyFromBlimpStore(blimpFilename, filename: string) =
  if not existsFile(blimpStore / blimpFilename):
    downloadFile(blimpFilename)
  copyFile(blimpStore / blimpFilename, filename)

# Delete from blimpStore and remote.
proc deleteFromBlimpStore(blimpFilename, filename: string) =
  if existsFile(blimpStore / blimpFilename):
    removeFile(blimpStore / blimpFilename)
  remoteDeleteFile(blimpFilename)

# Pick out blimpFilename (filename & "-" & hash)
proc blimpFileName(filename: string): string=
  var hashfile: File
  if not open(hashfile, filename):
    quit("Failed opening file: " & filename, 4)
  let hashline = split(string(readLine(hashfile)), {':'})
  if hashline[0] == "hash":
    result = hashline[1]
  else:
    result = nil

# Get hash and compute blimpFilename
proc computeBlimpFilename(filename: string): string =
  result = blimpFilename(filename)
  if result.isNil:
    var content: string
    try:
      content = readFile(filename)
    except:
      quit("Failed opening file: " & filename, 1)
    let hash = getMD5(content)
    result = filename & "-" & hash
 
# Copy original file to blimpStore and replace with hash stub in git.
proc deflate(filename: string) =
  let blimpFilename = computeBlimpFilename(filename)
  copyToBlimpStore(filename, blimpFilename)
  writeFile(filename, "hash:" & blimpFilename)
  echo("\t" & filename & " deflated.")

proc isInBlimpStore(filename: string): bool =
  let blimpFilename = blimpFilename(filename)
  if not blimpFilename.isNil:
    return true
  
# Parse out hash from hash stub and copy back original content from blimpStore.
proc inflate(filename: string) =
  let blimpFilename = blimpFilename(filename)
  if blimpFilename.isNil:
    echo("\t" & filename & " is not deflated, skipping.", 5)
  else:
    copyFromBlimpStore(blimpfilename, filename)
    echo("\t" & filename & " inflated.")

# Inflates file first (if deflated) and then removes current content for it,
# both locally and in remote.
proc remove(filename: string) =
  var blimpFilename = blimpFilename(filename)
  if not blimpFilename.isNil:
    copyFromBlimpStore(blimpfilename, filename)
  else:
    blimpFilename = computeBlimpFilename(filename)
  deleteFromBlimpStore(blimpfilename, filename)
  echo("\t" & filename & " content removed from blimpstore locally and remotely.")

# Find git root dir or fall back on current dir
proc gitRoot(): string =
  try:
    let tup = execCmdEx("git rev-parse --show-toplevel")
    if tup[1] == 0:
      result = tup[0]
    else:
      result = getCurrentDir()
  except:
    result = getCurrentDir()

let help = """
  blimp [options] <command> <filenames...>
    -v,--verbose             Verbosity
    <command>   (string)     (d)eflate, (i)nflate, delete, (c)heck, (r)ecover
    <filenames> (string...)  One or more filepaths to inflate/deflate
    
    Edit ~/blimpstore/.blimp.conf or <gitroot>/.blimp.conf and set a proper
    remote and also create ~/blimp.pass with the proper rsync password to use.
    
    Deflate is run before you add the big file to the index for committing.
    Deflate will replace the file contents with a hash, and copy the
    real content to ~/blimpstore, and if configured also upload it to
    remote, using rsync.
    
    Inflate will bring back the original content by copying from
    ~/blimpstore, and if its not there, first downloading from the remote.
    Use this whenever you need to work/edit the big file - in order to get
    its real content.
    
    Remove (no single character shortcut) will remove the file(s) content
    both from the local ~/blimpstore and from the remote. This only removes
    the current content version, not older versions. The file itself is first
    inflated, if needed, and not deleted. This only "unblimps" the file.
  """

################################ main #####################################

# Hardwired to "blimpstore" directory in home dir.
blimpStore = getHomeDir() / "blimpstore"

# Make sure we have the dir, or create it.
try:
  if not existsDir(blimpStore):
    createDir(blimpStore)
  if not existsFile(blimpStore / ".blimp.conf"):
    writeFile(blimpStore / ".blimp.conf", defaultConfig)
except:
  quit("Could not create " & blimpStore & " directory.", 1)


# Parse configuration files if they exist
# The one in gitroot overrides settings from the store.
parseConfFile(blimpStore / ".blimp.conf")
parseConfFile(gitRoot() / ".blimp.conf")


# Using lapp to get args
let args = parse(help)
let command = args["command"].asString
let filenames = args["filenames"].asSeq
verbose = args["verbose"].asBool

# Do the deed
if command == "d" or command == "deflate":
  for fn in filenames:
    deflate(fn.asString)
elif command == "i" or command == "inflate":
  for fn in filenames:
    inflate(fn.asString)
elif command == "remove":
  for fn in filenames:
    remove(fn.asString)
else:
  quit("Unknown command, only (d)eflate or (i)inflate are valid.", 6)

# All good
quit(0)